Silence websockets install echo

[sitka/sitka-tools.git] / marc_export_custom / stats-distribution.pl

#!/usr/bin/perl
use MARC::Batch;
use strict;
use warnings;
my $batch = MARC::Batch->new( 'USMARC', @ARGV );
$batch->strict_off();
$batch->warnings_off();
my %bibs;
my %holdings;
my $count_raw = 0;
my $count_copies = 0;
my $count_901c = 0;
while ( my $marc = $batch->next ) {
	$count_raw++;
	my $field_901c = $marc->subfield(901,"c");
	if(defined $field_901c) {
		chomp $field_901c;
		$count_901c++ if ($field_901c =~ /^.+$/);
	}

	my @field_852 = $marc->field(852);
	my %holding_libs;
	if(@field_852) {
		FIELD852: foreach my $my852 (@field_852) {
			my $my852b = $my852->subfield('b');
			next FIELD852 unless (defined $my852b and $my852b =~ /^.+$/);
			chomp $my852b;
			$holdings{$my852b} = 0 unless exists($holdings{$my852b});
			$holdings{$my852b}++;
			$holding_libs{$my852b} = 1;
		}
	}
	foreach(keys %holding_libs) {
		$bibs{$_} = 0 unless exists($bibs{$_});
		$bibs{$_}++;
	}
}

foreach my $lib (sort keys %bibs) {
	printf("bibs,%s,%d\n",$lib,$bibs{$lib});
}
foreach my $lib (sort keys %holdings) {
	printf("copies,%s,%d\n",$lib,$holdings{$lib});
	$count_copies += $holdings{$lib};
}

printf "summary,distinct-bibs-raw,%d\n",$count_raw;
printf "summary,distinct-bibs-901c,%d\n",$count_901c;
printf "summary,distinct-copies,%d\n",$count_copies;


# vim: ts=2 sw=2