Implement Overdrive data objects using data classes
[sitka/overdrive-evergreen-opac.git] / src / overdrive.coffee
1 # TODO memory leaks
2 #
3 # TODO Author/Title links could specify ebook filter
4 #
5 # TODO If logged in, could bypass place hold page and use action dialogue directly
6 #
7 # TODO Simple, cheap two-way data binding:
8 # We could publish a partial request object as an abstract way of making
9 # an API request, ie, od.$.triggerHandler 'od.metadata', id: id
10 # Subscribe to same event to receive reply object, ie,
11 # od.$.on 'od.metadata', (ev, reply) -> # do something with reply
12
13 require.config
14
15         paths:
16                 jquery:      'https://ajax.googleapis.com/ajax/libs/jquery/2.1.1/jquery.min'
17                 'jquery-ui': 'https://ajax.googleapis.com/ajax/libs/jqueryui/1.11.1/jquery-ui.min'
18                 lodash:      'https://cdnjs.cloudflare.com/ajax/libs/lodash.js/2.4.1/lodash.min'
19                 moment:      'https://cdnjs.cloudflare.com/ajax/libs/moment.js/2.5.1/moment.min'
20                 cookies:     'https://cdnjs.cloudflare.com/ajax/libs/Cookies.js/0.3.1/cookies.min'
21                 json:        'https://cdnjs.cloudflare.com/ajax/libs/json3/3.3.0/json3.min'
22
23         waitSeconds: 120
24
25 require [
26         'jquery'
27         'lodash'
28         'cookies'
29         'od_api'
30         'od_pages_opac'
31         'od_pages_myopac'
32         'od_action'
33 ], ($, _, C, od) ->
34
35         # Indicate the logged in status; the value is determined within document
36         # ready handler.
37         logged_in = false
38
39         # Various debugging functions; not used in production
40         log_page = -> console.log window.location.pathname
41         notify = (what) -> console.log "#{what} is in progress"
42         failed = (what) -> console.log "#{what} failed"
43         reload_page = -> window.location.reload true
44         replace_page = (href) -> window.location.replace href
45
46         # Query a search string of the current page for the value or existence of a
47         # property
48         search_params = (p) ->
49                 # Convert for example, '?a=1&b=2' to { a:1, b:2 }, 
50                 o =
51                         if xs = (decodeURI window.location.search)?.split('?')?[1]?.split('&')
52                                 _.zipObject( x.split('=') for x in xs )
53                         else
54                                 {}
55                 # Return either the value of a specific property, whether the property
56                 # exists, or the whole object
57                 if arguments.length is 1 then o[p] or o.hasOwnProperty p else o
58
59
60         # Return an abbreviation of the pathname of the current page,
61         # eg, if window.location.pathname equals 'eg/opac/record' or
62         # 'eg/opac/record/123', then return 'record', otherwise return ''
63         page_name = ->
64                 xs = window.location.pathname.match /eg\/opac\/(.+)/
65                 if xs then xs[1].replace /\/\d+/, '' else ''
66
67         # Make a map from an item ID to a status indicating whether it is on the
68         # holds list or the checkout list
69         # eg, var status = ids(holds, checkouts)[id]
70         item_status = (holds, checkouts) ->
71                 ids = {}
72                 ids[v.reserveId] = 'hold' for v, n in holds
73                 ids[v.reserveId] = 'checkout' for v, n in checkouts
74                 return ids
75
76         # Routing table: map an URL pattern to a handler that will perform actions
77         # or modify areas on the screen.
78         routes =
79
80                 # Scan through property names and execute the function value if the
81                 # name pattern matches against the window.location.pathname, eg,
82                 # routes.handle(). handle() does not try to execute itself.  Returns a
83                 # list of results for each handler that was executed. A result is
84                 # undefined if no subscriptions to an OD service was needed.
85                 handle: (p = window.location.pathname) ->
86                         for n, v of routes when n isnt 'handle'
87                                 v() if (new RegExp n).test p
88
89                 'eg\/opac': ->
90
91                         # Add a new dashboard to show total counts of e-items.
92                         # Start the dashboard w/ zero counts.
93                         $dash = $('#dash_wrapper')._dashboard()
94
95                         od.$.on
96
97                                 # Set the dashboard counts to summarize the patron's account
98                                 'od.interests': (ev, x) -> $dash._dashboard
99                                         ncheckouts:  x.nCheckouts
100                                         nholds:      x.nHolds
101                                         nholdsready: x.nHoldsReady
102
103                                 # Decrement the dashboard counts because an item has been
104                                 # removed from the holds or checkout list
105                                 'od.hold.delete': -> $dash._dashboard nholds: -1
106                                 'od.checkout.delete': -> $dash._dashboard ncheckouts: -1
107
108                                 # Log out of EG if we are logged in and if an OD patron access
109                                 # token seems to have expired
110                                 'od.logout': (ev, x) ->
111                                         if x is 'od'
112                                                 $('#logout_link').trigger 'click' if logged_in
113
114                 'opac\/myopac': ( this_page = page_name() ) ->
115
116                         # Add a new tab for e-items to the current page if it is showing a
117                         # system of tabs
118                         $('#acct_holds_tabs, #acct_checked_tabs')._etabs this_page, search_params 'e_items'
119                         # Relabel history tabs if they are showing on current page
120                         $('#tab_holds_history, #tab_circs_history')._tab_history()
121                         return
122
123                 'opac\/home': ->
124
125                         # Signal that EG may have logged out
126                         od.$.triggerHandler 'od.logout', 'eg' unless logged_in
127
128                 'opac\/login': ->
129
130                         # On submitting the login form, we initiate the login sequence with the
131                         # username/password from the login form
132                         $('form', '#login-form-box').one 'submit', ->
133                                 od.login
134                                         username: $('[name=username]').val()
135                                         password: $('[name=password]').val()
136
137
138                 # TODO In order to perform OD login after EG login, we could
139                 # automatically get the prefs page and scrape the barcode value,
140                 # but in the general case, we would also need the password value
141                 # that was previously submitted on the login page.
142
143                 # We could scrape the barcode value from the prefs page by having it
144                 # being parsed into DOM within an iframe (using an inscrutable sequence
145                 # of DOM traversal).  Unfortunately, it will reload script tags and
146                 # make XHR calls unnecessarily.
147                 #
148                 # The alternative is to GET the prefs page and parse the HTML string
149                 # directly for the barcode value, but admittedly, we need to use an
150                 # inscrutable regex pattern.
151
152                 # On the myopac account summary area, add links to hold list and
153                 # checkout list of e-items
154                 'myopac\/main': ( $table = $('.acct_sum_table') ) ->
155                         return unless $table.length
156
157                         totals = $table._account_summary()
158                         
159                         od.$.on 'od.interests', (ev, x) ->
160
161                                 $table._account_summary
162                                         ncheckouts:  totals[0]
163                                         nholds:      totals[1]
164                                         nready:      totals[2]
165                                         n_checkouts: x.nCheckouts
166                                         n_holds:     x.nHolds
167                                         n_ready:     x.nHoldsReady
168
169                 # Each time the patron's preferences page is shown, publish values that
170                 # might have changed because the patron has edited them.  Example
171                 # scenario: patron changes email address on the prefs page and then
172                 # places hold, expecting the place hold form to default to the newer
173                 # address.
174                 'myopac\/prefs': ->
175                         $tr = $('#myopac_summary_tbody > tr')
176                         em = $tr.eq(6).find('td').eq(1).text()
177                         bc = $tr.eq(7).find('td').eq(1).text()
178                         hl = $tr.eq(8).find('td').eq(1).text()
179                         od.$.triggerHandler 'od.prefs', email_address:em, barcode:bc, home_library:hl
180
181                 'opac\/results': (interested = {}) ->
182
183                         # List of hrefs which correspond to Overdrive e-items
184                         # TODO this list is duplicated in module od_pages_opac
185                         hrefs = [
186                                 'a[href*="downloads.bclibrary.ca"]' # Used in OPAC
187                                 'a[href*="elm.lib.overdrive.com"]' # Used in XUL staff client
188                         ]
189
190                         # Prepare each row of the results table which has an embedded
191                         # Overdrive product ID.  A list of Overdrive product IDs is
192                         # returned, which can be used to find each row directly.
193                         ids = $(hrefs.join ',').closest('.result_table_row')._results()
194                         return if ids?.length is 0
195
196                         od.$.on
197
198                                 # When patron holds and checkouts become available...
199                                 'od.interests': (ev, x) ->
200
201                                         # Initiate request for each Overdrive product ID
202                                         for id in ids
203                                                 od.apiMetadata id: id
204                                                 od.apiAvailability id: id
205
206                                         # Cache the relationship between product IDs and patron
207                                         # holds and checkouts, ie, has the patron placed a hold on
208                                         # an ID or checked out an ID?
209                                         interested = x.byID
210
211                                 # Fill in format values when they become available
212                                 'od.metadata': (ev, x) -> $("##{x.id}")._results_meta x
213
214                                 # Fill in availability values when they become available
215                                 'od.availability': (ev, x) ->
216                                         $("##{x.id}")
217                                                 ._results_avail x
218                                                 ._replace_place_hold_link x, interested[x.id]?.type
219
220                 'opac\/record': (interested = {}) ->
221
222                         # Add an empty container of format and availability values
223                         return unless id = $('div.rdetail_uris')._record()
224
225                         od.$.on
226
227                                 # When patron holds and checkouts become available...
228                                 'od.interests': (ev, x) ->
229
230                                         # Initiate request for metadata and availability values when
231                                         od.apiMetadata id: id
232                                         od.apiAvailability id: id
233
234                                         # Has the user placed a hold on an ID or checked out an ID?
235                                         interested = x.byID
236
237                                 # Fill in format values when they become available
238                                 'od.metadata': (ev, x) -> $("##{x.id}")._record_meta x
239
240                                 # Fill in availability values when they become available
241                                 'od.availability': (ev, x) ->
242                                         $("##{x.id}")._record_avail x
243                                         $('#rdetail_actions_div')._replace_place_hold_link x, interested[x.id]?.type
244
245                 # For the case where the patron is trying to place a hold if not logged
246                 # in, there is a loophole in the Availability API; if using a patron
247                 # access token and patron already has a hold on it, avail.actions.hold
248                 # will still be present, falsely indicating that patron may place a
249                 # hold, which will lead to a server error. The same situation will
250                 # occur if patron has already checked out.  It seems the OD server does
251                 # not check the status of the item wrt the patron before generating the
252                 # server response.
253                 #
254                 # To fix the problem, we will check if avail.id is already held or
255                 # checked out, and if so, then go back history two pages so that
256                 # original result list or record page is shown, with the proper action
257                 # link generated when the page reloads.
258
259                 # Replace the original Place Hold form with a table row to show
260                 # available actions, either 'Check out' or 'Place hold', depending on
261                 # whether the item is available or not, respectively.
262                 #
263                 # The following page handler does not replace the place_hold page, but
264                 # is meant to be called by the place hold link.
265                 # If the place_hold page is encountered, the handler will return
266                 # without doing anything, because no id is passed in.
267                 'opac\/place_hold': (id, interested = {}) ->
268                         return unless id
269
270                         $('#myopac_holds_div')._replace_title 'Place E-Item on Hold'
271                         $('#myopac_checked_div')._replace_title 'Check out E-Item'
272
273                         $('#holds_main, #checked_main, .warning_box').remove()
274
275                         $div = $('<div id="#holds_main">')
276                                 ._holds_main() # Add an empty table
277                                 ._holdings_row id # Add an empty row
278                                 .appendTo $('#myopac_holds_div, #myopac_checked_div')
279
280                         # Fill in metadata values when they become available
281                         od.$.on
282
283                                 'od.interests': (ev, x) ->
284                                         od.apiMetadata id: id
285                                         od.apiAvailability id: id
286                                         # Has the user placed a hold on an ID or checked out an ID?
287                                         interested = x.byID
288
289                                 'od.metadata': (ev, x) ->
290                                         $("##{x.id}")._row_meta x, 'thumbnail', 'title', 'author', 'formats'
291
292                                 'od.availability': (ev, x) ->
293                                         # Check if this patron has checked out or placed a hold on
294                                         # avail.id and if so, then go back two pages to the result list
295                                         # or record page. The page being skipped over is the login page
296                                         # that comes up because the user needs to log in before being
297                                         # able to see the place hold page.  Thus, the logic is only
298                                         # relevant if the user has not logged in before trying to place
299                                         # a hold.
300                                         if interested[x.id]?.type
301                                                 window.history.go -2
302                                         else
303                                                 $("##{x.id}")._holdings_row_avail x
304
305                 'myopac\/holds': ->
306
307                         # If we arrive here with an interested ID value, we are intending
308                         # to place a hold on an e-item
309                         if id = search_params 'interested'
310                                 return routes['opac\/place_hold'] id
311
312                         # Rewrite the text in the warning box to distinguish physical items from e-items
313                         unless search_params 'e_items'
314                                 $('.warning_box').text $('.warning_box').text().replace ' holds', ' physical holds'
315                                 return
316
317                         return unless ($holds_div = $('#myopac_holds_div')).length
318
319                         $holds_div._replace_title 'Current E-Items on Hold'
320
321                         $('#holds_main, .warning_box').remove()
322
323                         # Replace with an empty table for a list of holds for e-items
324                         $div = $('<div id="#holds_main">')
325                                 ._holds_main()
326                                 .appendTo $holds_div
327
328                         # Subscribe to notifications of relevant data objects
329                         od.$.on
330
331                                 'od.interests': (ev, x) ->
332
333                                         # Focus on patron's hold interests, and if the search
334                                         # parameters say so, further focus on holds of items that
335                                         # are ready to be checked out
336                                         holds = x?.ofHolds
337                                         holds = _.filter(holds, (x) -> x.actions.checkout) if search_params 'available'
338
339                                         # Add an empty list of holds
340                                         ids = $div._holds_rows holds
341
342                                         # Try to get the metadata and availability values for
343                                         # this hold
344                                         for id in ids
345                                                 od.apiMetadata id: id
346                                                 od.apiAvailability id: id
347
348                                 # Add metadata values to a hold
349                                 'od.metadata': (ev, x) -> $("##{x.id}")._row_meta x, 'thumbnail', 'title', 'author', 'formats'
350                                 # Add availability values to a hold
351                                 'od.availability': (ev, x) -> $("##{x.id}")._holds_row_avail x
352
353                                 'od.hold.update': (ev, x) ->
354                                         x = x.holds[0]
355                                         $("##{x.reserveId}")._holds_row x
356
357                                 'od.hold.delete': (ev, id) -> $("##{id}").remove()
358
359                 'myopac\/circs': ->
360
361                         # If we arrive here with an interested ID value, we are intending
362                         # to checking out an e-item
363                         if id = search_params 'interested'
364                                 return routes['opac\/place_hold'] id
365
366                         # Rewrite the text in the warning box to distinguish physical items from e-items
367                         unless search_params 'e_items'
368                                 $('.warning_box').text $('.warning_box').text().replace ' items', ' physical items'
369                                 return
370                         
371                         return unless ($checked_div = $('#myopac_checked_div')).length
372
373                         $checked_div._replace_title 'Current E-Items Checked Out'
374
375                         $('#checked_main, .warning_box').remove()
376
377                         # Build an empty table for a list of checkouts of e-items
378                         $div = $('<div id="#checked_main">')
379                                 ._checkouts_main()
380                                 .appendTo $checked_div
381
382                         # Subscribe to notifications of relevant data objects
383                         od.$.on
384
385                                 'od.interests': (ev, x) ->
386
387                                         # Fill in checkout list
388                                         ids = $div._checkouts_rows x?.ofCheckouts
389
390                                         # Try to get metadata values for these checkouts
391                                         od.apiMetadata id: id for id in ids
392
393                                 # Add metadata values to a checkout
394                                 'od.metadata': (ev, x) -> $("##{x.id}")._row_meta x, 'thumbnail', 'title', 'author'
395
396                                 'od.checkout.update': (ev, x) ->
397                                         x = x.checkouts[0]
398                                         $("##{x.reserveId}")._row_checkout x
399
400                                 'od.checkout.delete': (ev, id) -> $("##{id}").remove()
401
402         # Begin sequence after the DOM is ready...
403         $ ->
404
405                 return if window.IAMXUL # Comment out to run inside XUL staff client
406
407                 # We are logged into EG if indicated by a cookie or if running
408                 # inside XUL staff client.
409                 logged_in = Boolean C('eg_loggedin') or window.IAMXUL
410
411                 # Dispatch handlers corresponding to the current location
412                 # and return immediately if none of them require OD services
413                 return if _.every routes.handle() , (r) -> r is undefined
414
415                 # Try to get library account info
416                 od.apiLibraryInfo()
417
418                 # If we are logged in, we 'compute' the patron's interests in product
419                 # IDs; otherwise, we set patron interests to an empty object.
420                 .then ->
421
422                         # If logged in, ensure that we have a patron access token from OD
423                         # before getting patron's 'interests'
424                         if logged_in
425                                 od.login().then od.apiInterestsGet
426
427                         # Otherwise, return no interests
428                         # TODO should do the following in od_api module
429                         else
430                                 interests = byID: {}
431                                 od.$.triggerHandler 'od.interests', interests
432                                 return interests
433
434                 return
435         return